*  Program to compare all files in two libraries with 
*  a specified extension.  The files will be printed out with 
*  the labels BAD or OK, depending on whether they are identical 
*  or not.  The files in library 1 will serve as the model list.  

      str lib1.80,lib2.80,exten.10 
      str rec.80,file1.80,file2.80 
      str rec1.200,rec2.200 
      int flg 

      putc This is a program to compare all files in two libraries with 
      putc a specified extension.  The files will be printed out with 
      putc the labels BAD or OK, depending on whether they are identical 
      putc or not.  The files in library 1 will serve as the model list.  
      putc first library name?  
      getc lib1 
      putc second library name?  
      getc lib2 
      lib1 = trm(lib1) 
      lib2 = trm(lib2) 
      putc extension? (without dot) 
      getc exten 
      exten = exten // pad(3) 
      exten = exten{1,3} 
      exten = ucs(exten) 

       
      open [3,1] lib1      
      loop    
        getf [3] rec 
        rec = rec // pad(12) 
        rec = rec{1,12} 
        if rec{10,3} = exten 
          rec = rec{1,8} 
          rec = trm(rec) 
          rec = rec // "." // exten 
          putc ~rec  .t15 ...  
          file1 = lib1 // "\" // rec 
          file2 = lib2 // "\" // rec 
          open [1,1] file1 
          open [2,1] file2 
          flg = 0 
          loop 
            getf [1] rec1 
            getf [2] rec2 
            rec1 = trm(rec1) 
            rec2 = trm(rec2) 
            if rec1 <> rec2 
              putc BAD 
              goto NXT 
            end 
          repeat 
eof1: 
          flg = 1 
          getf [2] rec2 
          putc BAD 
          goto NXT 
eof2: 
          if flg = 0 
            putc BAD 
            goto NXT 
          end 
OK: 
          putc OK 
NXT: 
          close [1] 
          close [2] 
        end 
      repeat 
      run